// Creates w_cgsrmem_dv - Cognitive development markers: memory
// INPUT FILE - w_indresp.dta 
// OUTPUT FILE - w_cgsrmem_dv.dta

// WRITE FILEPATH WHERE YOU HAVE DOWNLOADED THE DATA
global in ""
// WRITE FILEPATH WHERE YOU WOULD LIKE TO SAVE THE OUTPUT FILE
global outpath ""


// 1 is for BHPS, 2 is for UKHLS
global cohort "2" 

foreach w in c { // INCLUDE WAVE LETTERS FOR THE WAVES NEEDED
global wave "`w'_"
global num=strpos("abcdefghijklmnopqrstuvwxyz","`w'")
global dta ""
global waveno=$num
global inpath "${in}/bhps_w${num}"
if $cohort==2 {
	global waveno=$num+18	
	global inpath "${in}/ukhls"
}


use pidp ${wave}memper ${wave}ivfio using  "${inpath}/${wave}indresp${dta}", clear

/*-------------ORIGINAL CODE--------------*/
// Cognitive development markers: memory
clonevar ${wave}cgsrmem_dv=${wave}memper
recode ${wave}cgsrmem_dv .=-9
lab var ${wave}cgsrmem_dv "Cognitive ability: Self-rated memory"
lab def ${wave}cgsrmem_dv -9"missing" -7"proxy" -2"refused", replace
lab def ${wave}cgsrmem_dv 1"excellent" 2"very good" 3"good", add
lab def ${wave}cgsrmem_dv 4 "fair" 5"poor", add
lab val ${wave}cgsrmem_dv ${wave}cgsrmem_dv
recode ${wave}memper (1/3=0) (4/5=1), gen(${wave}cgsrmem2_dv)
lab var ${wave}cgsrmem2_dv "Cognitive ability: Self rated memory, 2-category"
lab def ${wave}cgsrmem2_dv 0"excellent to good memory" 1"poor or fair memory", replace
lab def ${wave}cgsrmem2_dv -9 "missing" -8 "inapplicable" -7"proxy" -2"refused", add
lab val ${wave}cgsrmem2_dv ${wave}cgsrmem2_dv
fre ${wave}cgsrmem2_dv

isvar ${wave}cgsrmem2_dv ${wave}cgsrmem_dv
foreach x in `r(varlist)' {
		replace `x'=-7 if ${wave}ivfio==2
}
keep pidp ${wave}cgsrmem*
save "${outpath}/${wave}cgsrmem_dv", replace		
}