// Creates w_cgvf_dv -  Cognitive ability: Verbal fluency
// INPUT FILE - w_indresp.dta 
// OUTPUT FILE - w_cgvf_dv.dta

// WRITE FILEPATH WHERE YOU HAVE DOWNLOADED THE DATA
global in ""
// WRITE FILEPATH WHERE YOU WOULD LIKE TO SAVE THE OUTPUT FILE
global outpath ""



// 1 is for BHPS, 2 is for UKHLS
global cohort "2" 

foreach w in c { // INCLUDE WAVE LETTERS FOR THE WAVES NEEDED
global wave "`w'_"
global num=strpos("abcdefghijklmnopqrstuvwxyz","`w'")
global dta ""
global waveno=$num
global inpath "${in}/bhps_w${num}"
if $cohort==2 {
	global waveno=$num+18	
	global inpath "${in}/ukhls"
}


use "${inpath}/${wave}indresp${dta}", clear
set more off
drop *_dv

/*-------------ORIGINAL CODE--------------*/

* Verbal fluency test score
clonevar ${wave}cgvfc_dv = ${wave}vfct
lab var ${wave}cgvfc_dv "Cognitive ability: Verbal fluency: Count of correct answers"
fre ${wave}cgvfc_dv

clonevar ${wave}cgvfw_dv = ${wave}vftctw
lab var ${wave}cgvfw_dv "Cognitive ability: Verbal fluency: Count of incorrect answers"
fre ${wave}cgvfw_dv

// revfme interviewer observations
clonevar ${wave}cgivvf11_dv= ${wave}vfcont11
lab var ${wave}cgivvf11_dv "Cognitive ability: hh member present during Verbal fluency"
clonevar ${wave}cgivvf12_dv= ${wave}vfcont12
lab var ${wave}cgivvf12_dv "Cognitive ability: non-hh member present during Verbal fluency"
clonevar ${wave}cgivvf13_dv= ${wave}vfcont13
lab var ${wave}cgivvf13_dv "Cognitive ability: no-one present during Verbal fluency"

for var ${wave}vfcont11 ${wave}vfcont12 ${wave}vfcont13: replace X=. if X<0
	egen ${wave}cgivvf1_dv=group(${wave}vfcont11 ${wave}vfcont12 ${wave}vfcont13)
	replace ${wave}cgivvf1_dv=${wave}cgivvf11_dv if ${wave}cgivvf1_dv==.
	lab def ${wave}cgivvf1_dv  -9 "missing" -8 "inapplicable" -7"proxy" -2"refused" -1"don't know", replace
	lab def ${wave}cgivvf1_dv 1"no-one else present", add
	lab def ${wave}cgivvf1_dv 2"hh member present", add
	lab def ${wave}cgivvf1_dv 3"non-hh member present", add
	lab def ${wave}cgivvf1_dv 4"hh & non-hh member present", add
	lab val ${wave}cgivvf1_dv ${wave}cgivvf1_dv
	lab var ${wave}cgivvf1_dv "Cognitive ability: anyone present during Verbal fluency"

forvalues x=1(1)16 {
	clonevar ${wave}cgivvf2`x'_dv= ${wave}vfcont2`x'
    lab var ${wave}cgivvf2`x'_dv "Cognitive ability: pno `x' present during Verbal fluency"
	}
clonevar ${wave}cgivvf3_dv= ${wave}vfcont3
lab var ${wave}cgivvf3_dv "Cognitive ability: Other person helped w Verbal fluency"

forvalues x=1(1)8 {
 clonevar ${wave}cgivvfref`x'_dv= ${wave}vfstop`x'
 } 
clonevar ${wave}cgivvfref97_dv= ${wave}vfstop97 
lab var ${wave}cgivvfref1_dv "Cognitive ability: refused Verbal fluency: understanding of task"
lab var ${wave}cgivvfref2_dv "Cognitive ability: refused Verbal fluency: physical disability"
lab var ${wave}cgivvfref3_dv "Cognitive ability: refused Verbal fluency: attention problems"
lab var ${wave}cgivvfref4_dv "Cognitive ability: refused Verbal fluency: insufficient time"
lab var ${wave}cgivvfref5_dv "Cognitive ability: refused Verbal fluency: anxiety/discomfort"
lab var ${wave}cgivvfref6_dv "Cognitive ability: refused Verbal fluency: others present"
lab var ${wave}cgivvfref7_dv "Cognitive ability: refused Verbal fluency: R does not want to do task"
lab var ${wave}cgivvfref8_dv "Cognitive ability: refused Verbal fluency: language problems"
lab var ${wave}cgivvfref97_dv "Cognitive ability: refused Verbal fluency: other problem"

order pidp ${wave}cgvfc_dv ${wave}cgvfw_dv ${wave}cgivvf1_dv ${wave}cgivvf1*_dv ${wave}cgivvf2*_dv ///
    ${wave}cgivvf3_dv ${wave}cgivvfref*_dv
isvar ${wave}cgvfc_dv ${wave}cgvfw_dv ${wave}cgivvf1_dv
foreach x in `r(varlist)' {
		replace `x'=-7 if ${wave}ivfio==2
		}	
keep pidp ${wave}cgvfc_dv ${wave}cgvfw_dv ${wave}cgivvf1_dv 

lab dat "Cognitive ability: Verbal fluency, derived variables"

compress
save "${outpath}/${wave}cgvf_dv", replace
}