/// Creates w_yprelig_dv -  Religion: condensed GB-NI version.
// INPUT FILE - w_youth.dta 
// OUTPUT FILE - w_yprelig_dv.dta

// WRITE FILEPATH WHERE YOU HAVE DOWNLOADED THE DATA
global in ""
// WRITE FILEPATH WHERE YOU WOULD LIKE TO SAVE THE OUTPUT FILE
global outpath ""

// 1 is for BHPS, 2 is for UKHLS
global cohort "2" 
 
foreach w in a c e g { // INCLUDE WAVE LETTERS FOR THE WAVES NEEDED
global wave "`w'_"
global num=strpos("abcdefghijklmnopqrstuvwxyz","`w'")
global dta ""
global waveno=$num
global inpath "${in}/bhps_w${num}"
if $cohort==2 {
	global waveno=$num+18	
	global inpath "${in}/ukhls"
}


use "${inpath}/${wave}youth${dta}", clear
drop ${wave}yprelig_dv

if ${waveno}==19 {		
	gen ${wave}yprelig_dv=-9
	replace ${wave}yprelig_dv = 1 if (${wave}ypreliggb==1 | ${wave}ypreligni==1)
	replace ${wave}yprelig_dv = 2 if ((${wave}ypreliggb>=2 & ${wave}ypreliggb<=5 )|(${wave}ypreligni>=2 & ${wave}ypreligni<=11)) 
	replace ${wave}yprelig_dv = 3 if (${wave}ypreliggb==6 | ${wave}ypreligni==12)
	replace ${wave}yprelig_dv = 4 if (${wave}ypreliggb==7 | ${wave}ypreligni==13) 
	replace ${wave}yprelig_dv = 5 if ((${wave}ypreliggb>=8 & ${wave}ypreliggb<=10)| (${wave}ypreligni>=14 & ${wave}ypreligni<=17)) 
	replace ${wave}yprelig_dv = 6 if (${wave}ypreliggb==11 | ${wave}ypreligni==18) 
	lab def ${wave}yprelig_dv 1"none" 2"Christian" 3"Muslim" 4"Hindu" 5"Other" -1"Don't know" -9"missing", replace
	lab val ${wave}yprelig_dv ${wave}yprelig_dv
	lab var ${wave}yprelig_dv "Religion: condensed GB-NI version"
	}
if ${waveno}==21 | ${waveno}==25 {		
	gen ${wave}yprelig_dv=-9	
	replace ${wave}yprelig_dv = 1 if (${wave}ypreliggb==1 | ${wave}ypreligni==15)
	replace ${wave}yprelig_dv = 2 if ((${wave}ypreliggb>=2 & ${wave}ypreliggb<=11 )|(${wave}ypreligni>=1 & ${wave}ypreligni<=9))
	replace ${wave}yprelig_dv = 3 if (${wave}ypreliggb==12 | ${wave}ypreligni==13)
	replace ${wave}yprelig_dv = 4 if (${wave}ypreliggb==13 | ${wave}ypreligni==11)
	replace ${wave}yprelig_dv = 5 if ((${wave}ypreliggb>=14 & ${wave}ypreliggb<=17)| (${wave}ypreligni==10 | ${wave}ypreligni==14 | ${wave}ypreligni==16))
	replace ${wave}yprelig_dv = -1 if (${wave}ypreliggb==18 | ${wave}ypreligni==17)
	lab def ${wave}yprelig_dv 1"none" 2"Christian" 3"Muslim" 4"Hindu" 5"Other" -1"Don't know" -9"missing", replace
	lab val ${wave}yprelig_dv ${wave}yprelig_dv
	lab var ${wave}yprelig_dv "Religion: condensed GB-NI version"
	}
if ${waveno}==23 {		
	gen ${wave}yprelig_dv=-9	
	replace ${wave}yprelig_dv = 1 if (${wave}ypreliggb==1)
	replace ${wave}yprelig_dv = 2 if (${wave}ypreliggb>=2 & ${wave}ypreliggb<=11)
	replace ${wave}yprelig_dv = 3 if (${wave}ypreliggb==12)
	replace ${wave}yprelig_dv = 4 if (${wave}ypreliggb==13)
	replace ${wave}yprelig_dv = 5 if (${wave}ypreliggb>=14 & ${wave}ypreliggb<=17)
	replace ${wave}yprelig_dv = -1 if (${wave}ypreliggb==-1)
	lab def ${wave}yprelig_dv 1"none" 2"Christian" 3"Muslim" 4"Hindu" 5"Other" -1"Don't know" -9"missing", replace
	lab val ${wave}yprelig_dv ${wave}yprelig_dv
	lab var ${wave}yprelig_dv "Religion: condensed GB-NI version"
	}
	keep pidp ${wave}yprelig_dv
	save "${outpath}/${wave}yprelig_dv", replace
}